Fórum pro uživatele kancelářského balíku OpenOffice | LibreOffice
 

#1 27. 10. 2009 09:49:22

Helios
Člen
Registrace: 18. 5. 2005
Příspěvků: 43

převod souřadnic z 50°13´26´´ na 50,223889

Ahoj,
často dostávám data s GPS ouřadnicemi ve formátu 50°13´26´´, které ale do GISu potřebuju ve formátu 50,223889. Samozřejmě vlastní přepočet není problém, jen bych potřeboval to z toho původního formátu roztrhnout do 3 sloupců, abych to snadno přepočetl - např.:

50°13´26´´

na 3 sloupce 50  13  26 

Tuším, že na to byla nějaká funkce, ale nějak ji nemůžu najít. Nevěděl by někdo?

dík

Offline

#2 27. 10. 2009 16:40:57

Orinh
Člen
Registrace: 20. 6. 2006
Příspěvků: 17

Re: převod souřadnic z 50°13´26´´ na 50,223889

Pokud se lze spolehnout na pravidelný formát dvouciferných čísel, tak lze použít =MID(kde;zacatek;kolik znaků):

A1=50°13´26´´
st=MID(A1;1;2)
m=MID(A1;4;2)
s=MID(A1;7;2)

Možná existuje funkce na tento převod souřadnic, ale já jí neznám...

Offline

#3 28. 10. 2009 20:19:45

hanus
Člen
Místo Olomouc
Registrace: 29. 11. 2006
Příspěvků: 573
Web

Re: převod souřadnic z 50°13´26´´ na 50,223889

Uvedené vzorce jsou jednoduché, ale selžou, pokud stupně, minuty a sekundy nejsou dvouciferné. Univerzálnější, ale složitější jsou:
=LEFT(A1;SEARCH("°";A1)-1)
=MID(A1;SEARCH("°";A1)+1;SEARCH("´";A1)-SEARCH("°";A1)-1)
=MID(A1;SEARCH("´";A1)+1;SEARCH("´´";A1)-SEARCH("´";A1)-1)

Editoval hanus (28. 10. 2009 20:20:02)

Offline

#4 28. 10. 2009 20:52:13

lp.
Člen
Registrace: 24. 9. 2009
Příspěvků: 842

Re: převod souřadnic z 50°13´26´´ na 50,223889

Pokud zadáváte souřadnice z klávesnice, lze si vypomoci časem.

Prostě zadejte hodnotu 50°13´26´´ jako 50:13:26 (třeba do A1)

Pokud požadujete "správné" zobrazení, tak to srovná formát: [HH]"°"MM"´"SS"´´"
Potom hodnotu pro GIS 50,223889 dostanete rovnou vynásobením =A1 * 24

Pokud bude v A1 textová hodnota 50°13´26´´, potom hodnotu pro GIS dostanete vzorcem

=VALUE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A1;"°";":";1);"´";":";1);"´";""))*24

(aplikace předchozího postupu)

LP

Offline

Zápatí