Fórum pro uživatele kancelářského balíku OpenOffice | LibreOffice
 

#1 21. 6. 2013 10:40:12

Uhis
Člen
Registrace: 21. 6. 2013
Příspěvků: 2

Podmíněné seznamy - VYŘEŠENO

Dobrý den!
Řeším na první pohled jednoduchou úlohu, ale nedaří se mi ji vyřešit. Jedná se o seznam hodnot na základě předešlého výběru ze seznamu. Například v buňkách A1:A5 mám výrobce automobilů a k nim jsou pak v buňkách B1:G1 přiřazeny jednotlivé modely automobilů (B2:G2 pro dalšího atd). Jde mi o to jak udělat, abych měl v jedné rolovací nabídce výrobce automobilů a na základě tohoto prvního výběru bych měl v druhém seznamu (rolovací nabídce) výběr pouze z modelů dané automobilky.
Lámu si s tím hlavu poměrně dlouho a neúspěšně.
Děkuji, Pavel

_____________________________________________
Značím jako vyřešené

;o)

Editoval sedlacekdan (24. 6. 2013 19:10:13)

Offline

#2 21. 6. 2013 11:38:12

lp.
Člen
Registrace: 24. 9. 2009
Příspěvků: 771

Re: Podmíněné seznamy - VYŘEŠENO

Těch možností je docela dost.

Např. (jen vzorce):

A1: Výrobce
B1: Model

Použijeme funkci "Kontrola vstupních dat..."

V oblasti E1:G40 máme informace o výrobcích (první řádek) a vyráběných modelech další řádky pod výrobcem.


V buňce A1 zadejte "Kontrola vstupních dat...", Povolit rozsah buněk a do pole zadejte $List1.$E$1:$G$1

V buňce B1 zadejte "Kontrola vstupních dat...", Povolit rozsah buněk a do pole zadejte vzorec:

=OFFSET($E$1;1;MATCH($A$1;$E$1:$G$1;0)-1;COUNTA(INDEX($E$2:$G$40;0;MATCH($A$1;$E$1:$G$1;0)));1)

Není to tak hrozné, jak to možná vypadá:

=OFFSET(    ' Vyber oblast s modely zadaného výrobce
    $E$1;   ' Levý horní roh s daty
    1;      ' Druhý řádek (Offset počítá od 0)
    MATCH(  ' Najdi sloupec se zadaným výrobcem
          $A$1;        ' Hledej výrobce
          $E$1:$G$1;   ' V prvním řádku oblasti
          0            ' Přesná shoda
    ) -1;              ' Offset počítá od 0
    COUNTA(            ' Počet modelů (nesmí mezi modely být prázdné řádky)
           INDEX(      ' Sloupec s modely včetně prázdných řádků na konci
                 $E$2:$G$40;     ' Oblast se všemi modely všech výrobců (bez prvního řádku)
                 0;              ' Všechny řádky
                 MATCH(          ' Sloupec výrobce (stejné jako výše)
                       $A$1;$E$1:$G$1;0)));
    1       ' šířka 1 sloupec
)

Pokud chte vidět, co to dělá, můžete vzorec vložit do listu (jako maticový - ukládá se ctrl-shift-enter), tak můžete i ladit různé varianty.

Offline

#3 21. 6. 2013 16:42:11

Uhis
Člen
Registrace: 21. 6. 2013
Příspěvků: 2

Re: Podmíněné seznamy - VYŘEŠENO

Díky moc.
Funguje to, ale budu to muset vstřebat, protože funkce offset a match prakticky nepoužívám.
Díky!
Pavel

Offline

Zápatí