Fórum pro uživatele kancelářského balíku OpenOffice | LibreOffice
 

#1 2. 2. 2012 18:02:51

asfalt
Člen
Registrace: 8. 1. 2012
Příspěvků: 8

COUNTIF a SUMIF ako v MS Excel - VYŘEŠENO

Zdravim odbornikov,

potreboval by som poradit ako z jednej zakladne tabulky vybrat potrebne data pomocou COUNTIF a SUMIF ako je to v excel 2007+ kde na zadavanie viacero kriterii pre vyber sluzia funkcie COUNTIFS a SUMIFS

dakujem


________________________________________

Značím jako vyřešené

Editoval sedlacekdan (5. 2. 2012 19:49:06)

Offline

#2 2. 2. 2012 20:47:52

sedlacekdan
Moderátor
Místo Nehvizdy
Registrace: 21. 6. 2010
Příspěvků: 617

Re: COUNTIF a SUMIF ako v MS Excel - VYŘEŠENO

Tak nevím, jestli calc v základních funkcích toto podporuje.


Nezkoušel jste použít kontingenční tabulku? tam můžete pomocí filtru uplatnit až tři kritéria a používat základní funkce (sčítání, počet, průměr...)


Jak vytvořit kontingenční tabulku?


Úpravy kontingenční tabulky


;o)


Linux Mint 16 Petra - Apache OpenOffice 4.0.1
Pokud je Váš problém vyřešen, označte prosím svůj příspěvek za "VYŘEŠENÝ"
Zlepšíte tak orientaci na fóru při vyhledávání řešení problémů
JAK OZNAČIT TÉMA ZA VYŘEŠENÉ

Offline

#3 2. 2. 2012 21:42:39

hanus
Člen
Místo Olomouc
Registrace: 29. 11. 2006
Příspěvků: 573
Web

Re: COUNTIF a SUMIF ako v MS Excel - VYŘEŠENO

Calc SUMIFS a COUNTIFS nativně nepodporuje.
SUMIFS se řešilo už v příspěvku http://forum.openoffice.cz/viewtopic.php?id=575 (ať žije "hledat"!)
COUNTIFS by se řešilo zřejmě analogicky.

Offline

#4 2. 2. 2012 23:56:19

lp.
Člen
Registrace: 24. 9. 2009
Příspěvků: 806

Re: COUNTIF a SUMIF ako v MS Excel - VYŘEŠENO

Použijte buď maticové

sum(if(podmínka; hodnota; 0))

nebo

sum(podmínka * hodnota))

pro součet nebo

sum(if(podmínka; 1; 0))

nebo

sum(podmínka)

(oba vzorce maticově) pro počet


nebo obdobně

sumproduct

- ten je hůře pochopitelný, ale nemusí se zadávat maticově.

Příklad:

součet hodnot v C1:C10 z řádků, které mají ve sloupci A hodnotu 1 a ve sloupci B hodnotu 2:

=SUM(IF((A1:A10=1)*(B1:B10=2);C1:C10;0))

nebo

=SUM((A1:A10=1)*(B1:B10=2)*(C1:C10))

(oba vzorce maticově - vkládá se (CTRL - SHIFT - ENTER))

nebo

=SUMPRODUCT((A1:A10=1)*(B1:B10=2);C1:C10)

nebo

=SUMPRODUCT((A1:A10=1);(B1:B10=2);C1:C10)

Počet těchto hodnot:

=SUM(IF((A1:A10=1)*(B1:B10=2);1;0))

nebo

=SUM((A1:A10=1)*(B1:B10=2))

(oba vzorce maticově - vkládá se (CTRL - SHIFT - ENTER)

nebo

=SUMPRODUCT((A1:A10=1)*(B1:B10=2))

nebo

=SUMPRODUCT((A1:A10=1);(B1:B10=2))

(obyčejně)

Je zřejmé, že operátor násobení provádí logickou operaci "and". Pokud potřebujete podmínku "or" , podmínky sečtěte.


Ještě je někdy možné použít maticovou podobu funkcí sumif a countif.

Třeba takto:

=SUMIF(A1:A10&" "&B1:B10;1&" "&2;C1:C10)

a

=COUNTIF(A1:A10&" "&B1:B10;1&" "&2)

(obojí vložit jako matici "trojhmatem" (CTRL - SHIFT - ENTER), mezera ve vzorcích slouží k oddělení dvou čísel)

Editoval lp. (3. 2. 2012 11:37:34)

Offline

#5 10. 4. 2012 15:53:45

asfalt
Člen
Registrace: 8. 1. 2012
Příspěvků: 8

Re: COUNTIF a SUMIF ako v MS Excel - VYŘEŠENO

no akokolvek to skusam nedava mi to vysledok ako s funkciou sumifs()
situacia je takato
mam zakladnu tabulku s datami z ktorej potrebujem vytiahnut data do dalsich listov

v MSExcel pomocou funkcie SUMIFS dostanem hodnoty pri nasledovnom zadani funkcie

=sumifs($Výkony.$G$3:G$2000;$Výkony.$D$3:$D$2000;25;$Výkony.$F$3:$F$2000;A19;$Výkony.$J$3:$J$2000;105)
kde $Výkony.$G$3:G$2000 - zratavany rozsah
$Výkony.$D$3:$D$2000;25 - podmienka 1
$Výkony.$F$3:$F$2000;A19 - podmienka 2 - tu sa rata s hodnotou bunky A19 v aktualnom liste do ktoreho data zbieram
$Výkony.$J$3:$J$2000;105 - podmienka 3

obdobne prepisana funkcia do Calc mi sice zada hodnotu ale s vysledkom 0

=SUM(IF((Výkony.D3:D2000=24)*(Výkony.F3:F2000=A6)*(Výkony.J3:J2000=105);Výkony.G3:G2000;0))

je tam niekde chyba alebo v com je problem? obdobne mi to ychadza aj pri pouziti SUMPRODUCT

dakujem za vsetky rady

Offline

#6 10. 4. 2012 17:04:23

lp.
Člen
Registrace: 24. 9. 2009
Příspěvků: 806

Re: COUNTIF a SUMIF ako v MS Excel - VYŘEŠENO

Možnosti:

v podmínce 1. má být 24 nebo 25 ?

pokud vzorce kopírujete, je dobré použít absoutní adresy

Pokužil jste při zadání vzorce trojhmat (CTRL - SHIFT - ENTER)?

Vzorci z excelu odpovídá:

=SUMPRODUCT(Výkony.G3:G2000;1*(Výkony.$D$3:$D$2000=25)*(Výkony.$F$3:$F$2000=A6)*(Výkony.$J$3:$J$2000=105))

Offline

#7 10. 4. 2012 22:02:51

asfalt
Člen
Registrace: 8. 1. 2012
Příspěvků: 8

Re: COUNTIF a SUMIF ako v MS Excel - VYŘEŠENO

hmm takto mi to nefunguje, to cislo v podmienke 1 sa meni v zavislosti od toho co potrebujem vyhladat a zratat, ale ani takto ked som to zadal mi to nevypocitalo :-(

Offline

#8 10. 5. 2012 04:31:54

sedlacekdan
Moderátor
Místo Nehvizdy
Registrace: 21. 6. 2010
Příspěvků: 617

Re: COUNTIF a SUMIF ako v MS Excel - VYŘEŠENO

Vyzkoušejte verzi AOO 3.4 ta obsahuje nově právě funkce SUMIFS, COUNTIFS a další.

;o)


Linux Mint 16 Petra - Apache OpenOffice 4.0.1
Pokud je Váš problém vyřešen, označte prosím svůj příspěvek za "VYŘEŠENÝ"
Zlepšíte tak orientaci na fóru při vyhledávání řešení problémů
JAK OZNAČIT TÉMA ZA VYŘEŠENÉ

Offline

Zápatí