Fórum pro uživatele kancelářského balíku OpenOffice | LibreOffice
 

#1 29. 4. 2020 15:17:27

regine
Člen
Registrace: 11. 1. 2014
Příspěvků: 34

Vložit obsah z internet.stránky > ale obrázky zmenšit na šířku listu

Lze vložit zkopírovaný obsah z internetového prohlížeče do dokumentu, aby obrázky byly zmenšeny na danou velikost? Stačilo by zmenšit na velikost nepřesahující velikost dokumentu nebo šířku stránky.
Nejsem optimista, na netu jsem nic nenašel.
Doplněno po příspěvku od neutr.
Zpravidla se jedná o návody k různým zařízením. Autorské právo neporušuji, neb návod vytištěný mnohojazyčně mám a je k mé potřebě. Důvodem je, že si mohu ve Write udělat jen výňatek; případně překlad do češtiny. Asi víte, jaký balast odstraním. Popis mé činnosti:
- na internetové stránce označím oblast s textem a obrázky
- Ctrl+C
- Ctrl+V ve Write
- spousta obrázků má rozměr mimo stránku A4
- pracně obrázek po obrázku zmenšuji
Naposledy návod pro teplotní datalogger - zapisovač, titěrná nečitelná písmenka, český překlad zestručněný a zkomolené technické pojmy vůči verzi v angličtině.

Editoval regine (30. 4. 2020 06:50:27)


LibreOffice 6.2.8.2 užíván v Ubuntu, občas ve Windows

Offline

#2 29. 4. 2020 16:51:55

neutr
Člen
Registrace: 8. 3. 2007
Příspěvků: 3,435

Re: Vložit obsah z internet.stránky > ale obrázky zmenšit na šířku listu

Je několik způsobů vložení. Toto lze docílit jenom pomocí obrázku. Nejlépe pomocí PrintScreen a vložit Ctrl+V. Obrázek sice obsahuje také obraz celé pracovní plochy, ale to se dá oříznout tak aby tam byly jen obrysy browseru.


     Vlastní html se musí kopírovat jinak. Klepnete do okna browseru, uděláte výběr, nebo Ctrl+A, následně zkopírujete do sešitu. Máte tam sice klikačky, ale rozložení je pryč, objeví se nechtěné rámečky a také objekty které se zobrazí v původní velikosti. Asi Vám jde právě o tento způsob.
     Ale toto podle Vašeho požadavku opravdu nelze. Lze sice editovat vše a dosáhnout podobnosti. Když to uložíte zpět jako html tak to může vypadat stejně, ale ne vždy. Naše ukládání podporuje pouze obyčejné html. Běžně jsou webovky pod php, html5 a podobně.


     Existuje jedna hybridní možnost. Stáhnete obrázek a z něj uděláte "klikací mapu". Tam potom dáte všechny odkazy, respektive nasimulujete například makrem otevírání jako když by tam byl naveden Input/Output. Je to dost pracné, ne vše se dá suplovat, uživatel pozná, že to je divné. Ale je to schůdné.
     Jde tedy spíš o to, co s tím chcete následně dělat. Aby to chodilo ve Writeru je to právě tato možnost. Ale také hrozí do určité míry porušení autorských práv k různým autorům (stejně jako byste vytvořila kopii stránky klasickým způsobem).

Editoval neutr (29. 4. 2020 16:52:25)


Moje e-mailová adresa
Pokud je Váš problém vyřešen, označte prosím svůj příspěvek za "VYŘEŠENÝ"
Zlepšíte orientaci při vyhledávání řešení JAK OZNAČIT TÉMA ZA VYŘEŠENÉ

Offline

#3 30. 4. 2020 09:34:37

kamlan
Člen
Registrace: 15. 9. 2016
Příspěvků: 368

Re: Vložit obsah z internet.stránky > ale obrázky zmenšit na šířku listu

Pro alespoň nějaké usnadnění by mohlo pomoci malé makro. Kliknutím označíte obrázek (objeví se mu zelené čtverečky v rozích) a spustíte makro, kde zadáte o kolik procent mu chcete změnit rozměry.

Sub zmenaRozmeruObrazku 'změní rozměry obrázku ve Writeru
	const a=50 'výchozí hodnota v inputboxu
	dim oDoc, elem, oSize, iC as double
	iC=CLng(inputBox("%","Změnit rozměry obrázku na",a))/100 'inputbox
	oDoc=thisComponent
	elem=oDoc.getCurrentSelection() 'aktuální výběr
	if elem.supportsService("com.sun.star.text.TextGraphicObject") then 'jde o obrázek
		oSize=elem.size 'rozměry obrázku
		oSize.width=CLng(oSize.width*iC) 'znásobit šířku obrázku
		oSize.height=CLng(oSize.height*iC) 'znásobit výšku obrázku
		elem.size=oSize 'dát obrázku novou velikost
	end if
End Sub

Případně kdybyste měl stejné procento pro všechny obrázky, tak se to dá udělat ve smyčce aby je prostě zmenšil všechny

Editoval kamlan (30. 4. 2020 09:35:17)

Offline

#4 30. 4. 2020 12:09:52

regine
Člen
Registrace: 11. 1. 2014
Příspěvků: 34

Re: Vložit obsah z internet.stránky > ale obrázky zmenšit na šířku listu

to: kamlan - Díky, aspoň o něco snadnější.


LibreOffice 6.2.8.2 užíván v Ubuntu, občas ve Windows

Offline

#5 17. 5. 2020 17:05:23

Trambus
Člen
Registrace: 20. 2. 2013
Příspěvků: 50

Re: Vložit obsah z internet.stránky > ale obrázky zmenšit na šířku listu

Mám ten stejný problém jako tazetel, ovšem ve Wordu (bohužel musím používat i ten) - kdyby někdo věděl jak to nastavit tam, budu rád. smile

Možná by se k tomuto vláknu hodil i doplňující dotaz - lze nastavit defaultní vkládání obrázků s atributem: bez obtékání textu a přichytit jako znak? Mnohokrát do Writeru doplňuju tabulku z Calc vkládáním jako obrázek BMP a další kroky, které jsem uvedl jsou bohužel "otravné".

Díky. Pavel

Offline

#6 18. 5. 2020 09:03:23

kamlan
Člen
Registrace: 15. 9. 2016
Příspěvků: 368

Re: Vložit obsah z internet.stránky > ale obrázky zmenšit na šířku listu

S Wordem pomoci nemohu, ale pro to vkládání obrázku do Writeru rovnou jako znak (tím pádem nemá zapnuté ani obtékání) používám následující makro, normálně jsem si to přidal jako položku do menu Vložit
https://uloz.to/file/jq8D3GoG7nzm/obrazek-jako-znak-png


Sub vlozObr2 'vloží obrázek na pozici viditelného kurzoru s přednastaveným ukotvením a svislým zarovnáním
	dim oDoc, fSoub, sUrl, oVCur, oPos, oImg, oSel, oCur, document, dispatcher
	dim oSize as new com.sun.star.awt.Size
	oDoc=thisComponent
	document=oDoc.CurrentController.Frame : dispatcher=createUnoService("com.sun.star.frame.DispatchHelper")
	dispatcher.executeDispatch(document, ".uno:Escape", "", 0, array()) 'je-li něco označeno tak odznačit
	oVCur=oDoc.CurrentController.getViewCursor() 'viditelný kurzor (po odznačení je na konci bývalého výběru)
	oPos=oVCur.getStart() 'pozice viditelného kurzoru
	fSoub=CreateUnoService("com.sun.star.ui.dialogs.FilePicker") 'služba pro otevírací dialog souboru
	if fSoub.execute()=1 then 'je-li vybrán soubor
		sUrl=fSoub.files(0) 'cesta k vybranému souboru
	else 'nebyl vybrán soubor
		'msgbox("Nebyl vybrán žádný obrázek",48,"Chybný výběr obrázku") 'případné upozornšění že jste si nevybrali žádný soubor
		exit sub	
	end if
	fSoub.dispose() 'uvolnit otevírací službu
	oImg=oDoc.createInstance("com.sun.star.text.TextGraphicObject") 'objekt obrázku
	oImg.graphicUrl=sUrl 'url
	oImg.AnchorType=1 'UKOTVIT JAKO ZNAK =com.sun.star.text.TextContentAnchorType.AS_CHARACTER
	oImg.VertOrient=5 'SVISLE NA STŘED ZNAKU =com.sun.star.text.VertOrientation.CHAR_CENTER
	oImg.attach(oPos) 'vložit obrázek na pozici
	oSize=oImg.ActualSize 'původní velikost obrázku
	i=2/3 'koeficinet pro "změnu DPI" aby Libre obrázky nezvětšoval
	oSize.width=oSize.width*i : oSize.height=oSize.height*i
	oImg.Size=oSize 'nastavit přepočtenou velikost
End Sub

Makro je podrobně popsáno zde
https://uloz.to/file/M4P0ypuZnPLc/libre … o-znak-pdf

Editoval kamlan (18. 5. 2020 09:08:58)

Offline

Zápatí